How to use

This is the main source code for the experiment. If you want to use it, you should copy the actual zip file to your own PsyToolkit account, because often there are other files included for stimuli.

The source code for ldt

bitmaps
  instructions
  fixpoint

fonts
  arial 40

table words
  "DOCTOR" "NURSE"  "related"   1 1 
  "DOCTOR" "FLIPO"  "nonword"   3 2
  "TREE"   "DOCTOR" "unrelated" 2 1
  "DOCTOR" "NURSE"  "unrelated" 2 1
  "DOCTOR" "FLIPO"  "nonword"   3 2
  "BUTTER" "BREAD"  "related"   1 1
  "BREAD"  "DOCTOR" "unrelated" 2 1
  "SOAM"   "GLOVE"  "nonword"   3 2
  "NART"   "TRIEF"  "nonword"   3 2
  "PLAME"  "WINE"   "nonword"   3 2

task lexical
  table words
  keys a l
  show bitmap fixpoint
  delay 500
  clear 1
  delay 500
  show text @1 0 -25
  show text @2 0  25
  readkey @5 2000
  clear 2 3
  if STATUS == CORRECT
    show text "correct!"
    delay 500
    clear 4
  fi
  if STATUS != CORRECT
    show text "wrong response, or too slow!"
    delay 1500
    clear 4
  fi
  save BLOCKNAME TABLEROW @1 @2 @3 @4 RT TT STATUS

message instructions

block training
  tasklist
    lexical 10 all_before_repeat
  end
  feedback
    set &Related mean c7   ; select c6 == 1 && c9 == 1
    set &Unrelated mean c7 ; select c6 == 2 && c9 == 1
    set &Nonword mean c7   ; select c6 == 3 && c9 == 1
    text -200 -200 &Related   ; prefix "Related words: " ; postfix " ms"
    text -200 -50 &Unrelated ; prefix "Unrelated words: " ; postfix " ms"
    text -200 100 &Nonword   ; prefix "Nonsense word(s): " ; postfix " ms"
    text -200 200 "Press space to continue"
  end