How to use

This is the main source code for the experiment. If you want to use it, you should copy the actual zip file to your own PsyToolkit account, because often there are other files included for stimuli.

The source code for pacedreading1

table sent
  "John brought cookies for his mother"
  "Mary cooked dinner for her son"
  "Clara is looking after her pets"
  "Mickey likes to take walks with Minnie"
  "Minnie enjoys to spend time with Mickey"
  "Daisy likes gardening"

fonts
  normal arial 20
  big arial 40

task paced
  keys n
  font normal
  show text "Press the n key to start see the first word." 0 -50
  show text "Then press the n key each time for the following words." 0  50
  readkey 1 9999
  clear -1 -2
  set %%words split @1
  set $l %%words size ## how many words
  set $mycounter 1
  set &&reactionTimes clear
  font big
  while $mycounter <= $l
    show text %%words[$mycounter]
    readkey 1 9999
    clear -1
    set &&reactionTimes append RT
    set $mycounter increase
  while-end
  set $totalTime &&reactionTimes sum
  font normal
  show text "Well done...just wait until next sentence"
  delay 500
  show text ".  "  0 30
  delay 500
  show text ".. "  0 30
  delay 500
  show text "..."  0 30
  delay 500
  clear screen
  set %sentence @1
  save $l $totalTime %sentence &&reactionTimes
  
block test
  message "A self-paced reading task. Press space to continue."
  tasklist
    paced 5
  end